main_optim.F90

Go to the documentation of this file.

!! =============================================================================
!!  This file is part of the mmg software package for the tetrahedral
!!  mesh modification.
!!  Copyright (c) Bx INP/Inria/UBordeaux/UPMC, 2004- .
!!
!!  mmg is free software: you can redistribute it and/or modify it
!!  under the terms of the GNU Lesser General Public License as published
!!  by the Free Software Foundation, either version 3 of the License, or
!!  (at your option) any later version.
!!
!!  mmg is distributed in the hope that it will be useful, but WITHOUT
!!  ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
!!  FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public
!!  License for more details.
!!
!!  You should have received a copy of the GNU Lesser General Public
!!  License and of the GNU General Public License along with mmg (in
!!  files COPYING.LESSER and COPYING). If not, see
!!  <http://www.gnu.org/licenses/>. Please read their terms carefully and
!!  use this copy of the mmg distribution only if you accept them.
!! =============================================================================
!!
 
 
PROGRAM main
 
  IMPLICIT NONE
 
! if the header file is in the "include" directory
! #include "libmmg3df.h"
 
! if the header file is in "include/mmg/mmg3d"
#include "mmg/mmg3d/libmmg3df.h"
 
  mmg5_data_ptr_t    :: mmgmesh
  mmg5_data_ptr_t    :: mmgls
  INTEGER            :: ier,argc
  CHARACTER(len=300) :: exec_name,inname,outname,lsname
  INTEGER,PARAMETER :: immg = mmg5f_int
 
  WRITE(*,*) "  -- TEST MMG3DLIB"
 
  argc =  command_argument_count();
  CALL get_command_argument(0, exec_name)
 
  IF ( argc /=3 ) THEN
     print*," Usage: ",trim(exec_name)," meshfile lsfile meshout"
     CALL exit(1);
  ENDIF
 
  ! Name and path of the mesh file
  CALL get_command_argument(1, inname)
  CALL get_command_argument(2, lsname)
  CALL get_command_argument(3, outname)
 
 
  mmgmesh = 0
  mmgls   = 0
 
  CALL mmg3d_init_mesh(mmg5_arg_start, &
       mmg5_arg_ppmesh,mmgmesh,mmg5_arg_ppls,mmgls, &
       mmg5_arg_end)
 
  !!------------------- Level set discretization option ---------------------
  ! Ask for level set discretization: note that it is important to do this step
  ! here because in iso mode, some filters are applied at mesh loading
  !
  ! Pass 0_8 (0 at 64 bytes precision) if you don't want to pass the mmgLs
  ! structure (unused argument of Set_iparameter functions).
  CALL mmg3d_set_iparameter(mmgmesh,0_8,mmg3d_iparam_iso, 1_immg,ier)
  IF ( ier == 0 )  CALL exit(101)
 
  ! Ask for optim mode: compute the mean of input edge lengths.
  CALL mmg3d_set_iparameter(mmgmesh,0_8,mmg3d_iparam_optim, 1_immg,ier)
  IF ( ier == 0 )  CALL exit(101)
 
  ! Ask to do this with anisotropic metric (unit tensor metric is computed).
  CALL mmg3d_set_iparameter(mmgmesh,0_8,mmg3d_iparam_anisosize, 1_immg,ier)
  IF ( ier == 0 )  CALL exit(101)
 
 
  CALL mmg3d_loadmesh(mmgmesh,trim(adjustl(inname)),&
       len(trim(adjustl(inname))),ier)
  IF ( ier == 0 )  CALL exit(102)
 
 
  CALL mmg3d_loadsol(mmgmesh,mmgls,trim(adjustl(lsname)),&
       len(trim(adjustl(lsname))),ier)
  IF ( ier /= 1 ) THEN
     CALL exit(104)
  ENDIF
 
  CALL mmg3d_chk_meshdata(mmgmesh,mmgls,ier)
  IF ( ier /= 1 ) CALL exit(105)
 
  CALL mmg3d_mmg3dls(mmgmesh,mmgls,%val(0_8),ier)
 
  IF ( ier == mmg5_strongfailure ) THEN
     print*,"BAD ENDING OF MMG3DLIB: UNABLE TO SAVE MESH"
     stop 2
  ELSE IF ( ier == mmg5_lowfailure ) THEN
     print*,"BAD ENDING OF MMG3DLIB"
  ENDIF
 
 
  CALL mmg3d_savemesh(mmgmesh,trim(adjustl(outname)),&
       len(trim(adjustl(outname))),ier)
  IF ( ier /= 1 ) THEN
     CALL exit(106)
  ENDIF
 
  CALL mmg3d_free_all(mmg5_arg_start, &
       mmg5_arg_ppmesh,mmgmesh,mmg5_arg_ppls,mmgls, &
       mmg5_arg_end)
 
END PROGRAM