main.F90

Go to the documentation of this file.

 
 
PROGRAM main
 
  IMPLICIT NONE
 
  ! if the header file is in the "include" directory
  ! #include "libmmg3df.h"
 
  ! if the header file is in "include/mmg/mmg3d"
#include "mmg/mmg3d/libmmg3df.h"
 
  mmg5_data_ptr_t    :: mmgmesh
  mmg5_data_ptr_t    :: mmgsol,mmgmet,tmpsol
  INTEGER            :: ier,argc,opt,i4
 
  !! To manually recover the mesh
  INTEGER(MMG5F_INT) :: np,j
  INTEGER            :: nsol,typsol(mmg5_nsols_max)
  REAL(kind=8),dimension(:),ALLOCATABLE :: sols
 
  CHARACTER(len=300) :: exec_name,filename,fileout,option
 
  print*,"  -- TEST MMG3DLIB"
 
  argc =  command_argument_count();
  CALL get_command_argument(0, exec_name)
 
 
  IF ( argc /=3 ) THEN
     print*," Usage: ",trim(adjustl(exec_name)),&
          " input_file_name output_file_name io_option"
     print*,"     io_option = 0 to Get/Set the solution field by field"
     print*,"     io_option = 1 to Get/Set the solution field by field&
          & and vertex by vertex"
     CALL exit(1);
  ENDIF
 
  ! Name and path of the mesh file
  CALL get_command_argument(1, filename)
  CALL get_command_argument(2, fileout)
  CALL get_command_argument(3, option)
 
  READ(option, '(I2)') opt
 
  !!> ------------------------------ STEP   I --------------------------
  !! 1) Initialisation of mesh and sol structures */
  !! args of InitMesh:
  !! MMG5_ARG_start: we start to give the args of a variadic func
  !! MMG5_ARG_ppMesh: next arg will be a pointer over a MMG5_pMesh
  !! &mmgMesh: pointer to your MMG5_pMesh (that stores your mesh)
  !! MMG5_ARG_ppMet: next arg will be a pointer over a MMG5_pSol storing a metric
  !! &mmgSol: pointer to your MMG5_pSol (that stores your metric)
 
  mmgmesh = 0
  mmgsol  = 0
  mmgmet  = 0
  tmpsol  = 0
 
  CALL mmg3d_init_mesh(mmg5_arg_start, &
       mmg5_arg_ppmesh,mmgmesh,mmg5_arg_ppmet,mmgmet, &
       mmg5_arg_end);
 
 
  !!> 2) Build initial mesh and solutions in MMG5 format
  !! Two solutions: just use the MMG3D_loadMesh function that will read a .mesh(b)
  !! file formatted or manually set your mesh using the MMG3D_Set* functions
 
  !!> Automatic loading of the mesh and multiple solutions
  CALL mmg3d_loadmesh(mmgmesh,trim(adjustl(filename)),&
       len(trim(adjustl(filename))),ier)
  IF ( ier /= 1 )  CALL exit(102)
 
  CALL mmg3d_loadallsols(mmgmesh,mmgsol,trim(adjustl(filename)),&
       len(trim(adjustl(filename))),ier)
  IF ( ier /= 1 )  CALL exit(103)
 
  !!> ------------------------------ STEP II ---------------------------
 
  !!> 3) Transfer the solutions in a new solutions array
  !! a) Get the solutions sizes
  CALL mmg3d_get_solsatverticessize(mmgmesh,mmgsol,nsol,np,typsol,ier)
  IF ( ier /= 1 )  CALL exit(104)
 
  !!> b) Manually set the size of the new solution: give info for the sol
  !! structure: number of solutions, type of entities on which applied the
  !! solutions, number of vertices, type of the solution */
  CALL mmg3d_set_solsatverticessize(mmgmesh,tmpsol,nsol,np,typsol,ier)
  IF ( ier /= 1 )  CALL exit(105)
 
  !!> c) Get each solution and set it in the new structure
 
  !!> b) give solutions values and positions
  !! Get the entire field of a given solution
  DO i4=1,nsol
 
    IF ( opt==0 ) THEN
       ! Get the ith solution array
       IF ( typsol(i4) == mmg5_scalar ) THEN
          ALLOCATE(sols(np))
       ELSE IF ( typsol(i4) == mmg5_vector ) THEN
          ALLOCATE(sols(3*np))
       ELSE IF ( typsol(i4) == mmg5_tensor ) THEN
          ALLOCATE(sols(6*np))
       ENDIF
 
       CALL mmg3d_get_ithsols_insolsatvertices(mmgsol,i4,sols,ier)
       IF ( ier /= 1 )  CALL exit(107)
 
       ! Set the ith solution in the new structure
       CALL mmg3d_set_ithsols_insolsatvertices(tmpsol,i4,sols,ier)
       IF ( ier /= 1 )  CALL exit(108)
    ELSE
      IF ( typsol(i4) == mmg5_scalar ) THEN
          ALLOCATE(sols(1))
       ELSE IF ( typsol(i4) == mmg5_vector ) THEN
          ALLOCATE(sols(3))
       ELSE IF ( typsol(i4) == mmg5_tensor ) THEN
          ALLOCATE(sols(6))
       ENDIF
 
       DO j=1,np
          ! Get and set the ith solution array vertex by vertex
          CALL mmg3d_get_ithsol_insolsatvertices(mmgsol,i4,sols,j,ier)
          IF ( ier /= 1 )  CALL exit(107)
 
          ! Set the ith solution in the new structure
          CALL mmg3d_set_ithsol_insolsatvertices(tmpsol,i4,sols,j,ier)
          IF ( ier /= 1 )  CALL exit(108)
       ENDDO
    ENDIF
 
    DEALLOCATE(sols)
  ENDDO
 
 
  !!> ------------------------------ STEP III --------------------------
  !! Save the new data
  !! Use the MMG3D_saveMesh/MMG3D_saveAllSols functions
  !! save the mesh
  CALL mmg3d_savemesh(mmgmesh,trim(adjustl(fileout)),len(trim(adjustl(fileout))),ier)
  IF ( ier /= 1 ) CALL exit(110)
 
  ! save the solutions array
  CALL mmg3d_saveallsols(mmgmesh,tmpsol,trim(adjustl(fileout)), &
       len(trim(adjustl(fileout))),ier)
  IF ( ier /= 1 ) CALL exit(111)
 
  !!> 3) Free the MMG3D structures
  CALL mmg3d_free_allsols(mmgmesh,mmgsol,ier)
 
  CALL mmg3d_free_all(mmg5_arg_start, &
       mmg5_arg_ppmesh,mmgmesh,mmg5_arg_ppsols,tmpsol, &
       mmg5_arg_end)
 
END PROGRAM main