main.F90

Go to the documentation of this file.

!! =============================================================================
!!  This file is part of the mmg software package for the tetrahedral
!!  mesh modification.
!!  Copyright (c) Bx INP/Inria/UBordeaux/UPMC, 2004- .
!!
!!  mmg is free software: you can redistribute it and/or modify it
!!  under the terms of the GNU Lesser General Public License as published
!!  by the Free Software Foundation, either version 3 of the License, or
!!  (at your option) any later version.
!!
!!  mmg is distributed in the hope that it will be useful, but WITHOUT
!!  ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
!!  FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public
!!  License for more details.
!!
!!  You should have received a copy of the GNU Lesser General Public
!!  License and of the GNU General Public License along with mmg (in
!!  files COPYING.LESSER and COPYING). If not, see
!!  <http://www.gnu.org/licenses/>. Please read their terms carefully and
!!  use this copy of the mmg distribution only if you accept them.
!! =============================================================================
!!
 
! Example of use of the mmg3dls function of the mmg3d library (basic use of
! level-set discretization option): here the user
! provide a level-set and a metric on which he want to adapt the final mesh
!
! @author Charles Dapogny (LJLL, UPMC)
! @author Pascal Frey (LJLL, UPMC)
! @author Algiane Froehly (Inria / IMB, Université de Bordeaux)
! @version 5
! @copyright GNU Lesser General Public License.
!
 
PROGRAM main
 
  IMPLICIT NONE
 
! if the header file is in the "include" directory
! #include "libmmg3df.h"
 
! if the header file is in "include/mmg/mmg3d"
#include "mmg/mmg3d/libmmg3df.h"
 
  mmg5_data_ptr_t    :: mmgmesh
  mmg5_data_ptr_t    :: mmgls,mmgmet
  INTEGER            :: ier,argc
  INTEGER(MMG5F_INT) :: k,np
  CHARACTER(len=300) :: exec_name,inname,outname,lsname
  INTEGER,PARAMETER :: immg = mmg5f_int
 
  WRITE(*,*) "  -- TEST MMG3DLIB"
 
  argc =  command_argument_count();
  CALL get_command_argument(0, exec_name)
 
  IF ( argc /=3 ) THEN
     print*," Usage: ",trim(exec_name)," meshfile lsfile meshout"
     CALL exit(1);
  ENDIF
 
  ! Name and path of the mesh file
  CALL get_command_argument(1, inname)
  CALL get_command_argument(2, lsname)
  CALL get_command_argument(3, outname)
 
  ! 1) Initialisation of mesh and sol structures
  ! args of InitMesh:
  ! MMG5_ARG_start: we start to give the args of a variadic func
  ! MMG5_ARG_ppMesh: next arg will be a pointer over a MMG5_pMesh
  ! mmgMesh: your MMG5_pMesh (that stores your mesh)
  ! MMG5_ARG_ppLs: next arg will be a pointer over a MMG5_pSol storing a level-set
  ! mmgLs: pointer to your MMG5_pSol (that stores your level-set)
  ! MMG5_ARG_ppMet: next arg will be a pointer over a MMG5_pSol that will
  ! store the input metric
  ! mmgMet: pointer to your MMG5_pSol (that will store the input metric)
  mmgmesh = 0
  mmgls   = 0
  mmgmet  = 0
 
  CALL mmg3d_init_mesh(mmg5_arg_start, &
       mmg5_arg_ppmesh,mmgmesh,mmg5_arg_ppls,mmgls, &
       mmg5_arg_ppmet,mmgmet, &
       mmg5_arg_end)
 
  !!------------------- Level set discretization option ---------------------
  ! Ask for level set discretization: note that it is important to do this step
  ! here because in iso mode, some filters are applied at mesh loading
  CALL mmg3d_set_iparameter(mmgmesh,mmgls,mmg3d_iparam_iso, 1_immg,ier)
  IF ( ier == 0 )  CALL exit(101)
 
 
  CALL mmg3d_loadmesh(mmgmesh,trim(adjustl(inname)),&
       len(trim(adjustl(inname))),ier)
  IF ( ier == 0 )  CALL exit(102)
 
  ! Two solutions: just use the MMG3D_loadSol function that will read a .sol(b)
  !    file formatted or manually set your level-set using the MMG3D_Set* functions
 
  CALL mmg3d_loadsol(mmgmesh,mmgls,trim(adjustl(lsname)),&
       len(trim(adjustl(lsname))),ier)
  IF ( ier /= 1 ) THEN
     CALL exit(104)
  ENDIF
 
  ! ------------------- Give the Metric to Mmg ------------------------------
  ! Manually for example
  ! a) give info for the metric: the metric is applied on vertex
  !    entities, number of vertices np is recoverd using get_meshSize and the sol
  !    is tensorial
  CALL mmg3d_get_meshsize(mmgmesh,np,%val(0_immg),%val(0_immg),&
       %val(0_immg),%val(0_immg),%val(0_immg),ier)
  IF ( ier /= 1 ) THEN
     CALL exit(204)
  ENDIF
 
 
  CALL mmg3d_set_solsize(mmgmesh,mmgmet,mmg5_vertex,np,mmg5_tensor,ier)
  IF ( ier /= 1 ) THEN
     CALL exit(304)
  ENDIF
 
  ! b) give metric values and positions
  DO k=1,np
     ! the Metric is constant over the mesh and follow the canonical
     ! directions: it is given by the tensor (10000,0,100)
     CALL mmg3d_set_tensorsol(mmgmet,10.d0,0.d0,0.d0,1.d0,0.d0,1.d0,k,ier)
     IF ( ier /= 1 ) THEN
        CALL exit(404)
     ENDIF
  ENDDO
 
  CALL mmg3d_chk_meshdata(mmgmesh,mmgls,ier)
  IF ( ier /= 1 ) CALL exit(105)
 
  ! isovalue discretization followed by an adaptation step over the input
  ! Metric mmgMet. The mmgMet structure is updated so at the end it contains
  ! the output metric of Mmg.
  CALL mmg3d_mmg3dls(mmgmesh,mmgls,mmgmet,ier)
 
  IF ( ier == mmg5_strongfailure ) THEN
     print*,"BAD ENDING OF MMG3DLIB: UNABLE TO SAVE MESH"
     stop 2
  ELSE IF ( ier == mmg5_lowfailure ) THEN
     print*,"BAD ENDING OF MMG3DLIB"
  ENDIF
 
 
  CALL mmg3d_savemesh(mmgmesh,trim(adjustl(outname)),&
       len(trim(adjustl(outname))),ier)
  IF ( ier /= 1 ) THEN
     CALL exit(106)
  ENDIF
 
  CALL mmg3d_savesol(mmgmesh,mmgmet,trim(adjustl(outname)),&
       len(trim(adjustl(outname))),ier)
  IF ( ier /= 1 ) THEN
     CALL exit(107)
  ENDIF
 
  CALL mmg3d_free_all(mmg5_arg_start, &
       mmg5_arg_ppmesh,mmgmesh,mmg5_arg_ppls,mmgls, &
       mmg5_arg_ppmet,mmgmet, &
       mmg5_arg_end)
 
END PROGRAM